pro apply_factors, old_images, new_images, WNEWIM=wnew, REDISPLAY=redisp
;+
; NAME:
;	apply_factors
; PURPOSE:
;	Match image names and apply factors & offsets
;			of old_images to new_images.
; CALLING EXAMPLE:
;	apply_factors, old_images, new_images, /REDISPLAY
; INPUTS:
; KEYWORDS:
; OUTPUTS:
; EXTERNAL CALLS:
; COMMON BLOCKS:
; PROCEDURE:
; MODIFICATION HISTORY:
;	Written, Frank Varosi NASA/GSFC 1991.
;-
	if ( N_struct( new_images ) LE 0 ) OR $
	   ( N_struct( old_images ) LE 0 ) then return

	match, old_images.Name, new_images.Name, wold, wnew

	Nmatch = N_elements( wold )

	if (Nmatch LE 0) then begin
		print," No corresponding images, no Factors applied"
		return
	   endif else print," applying factors & offsets to",Nmatch,"  images"

	Factors = old_images(wold).Factor
	Offsets = old_images(wold).Offset

	new_images(wnew).Factor = Factors * new_images(wnew).Factor
	new_images(wnew).Offset = Factors * new_images(wnew).Offset + Offsets

	for i=0,Nmatch-1 do begin

		im = wnew(i)
		image = Factors(i) * new_images(im).image + Offsets(i)
		new_images(im).image = image
		new_images(im).Min = min( image, MAX=maxim )
		new_images(im).Max = maxim
	  endfor

	scale_images, new_images
	if keyword_set( redisp ) then display_images, new_images
return
end