pro contour_mark_op, mark_Lab, attributes
;+
; NAME:
;	contour_mark_op
; PURPOSE:
;	Perform sets and changes of source marks and Labels,
;	for pro contour_markset.
; CALLING:
;	contour_mark_op, mark_Lab, attributes
; INPUTS:
;	mark_Lab = structure, the mark(s) or Label(s).
;	attributes = string, specifying what to modify.
; INPUTS:
;	mark_Lab = structure, the modified mark(s) or Label(s).
; EXTERNAL CALLS:
;	function N_struct
;	function next_word
; HISTORY:
;	written: Frank Varosi NASA/GSFC 1991.
;-
	if N_struct( mark_Lab ) LE 0 then return
	tags = tag_names( mark_Lab )

	CASE attributes(0) OF

	  "color": BEGIN
			if (max( tags EQ "SYMBOL")) then what="source" $
						    else what="Label"
			menu = ["select " + what + " color:",	$
				"dark (min)",			$
				"bright (max)",			$
				"variable with adjct"		]
			copt = wmenu( menu, INIT=2, TIT=0 )
			mark_Lab.color =(!D.table_size-copt+1) MOD !D.table_size
			print," color #: ",mark_Lab(0).color
		     END

	  "size": BEGIN
		if (max( tags EQ "SYMBOL")) then begin
			menu = ["select source mark size:",$
				strtrim( indgen(10)+1 )+" %" ]
			init = fix( mark_Lab(0).size * 100 )
			sel = wmenu( menu, INIT=init, TIT=0 )
			if (sel GT 0) then begin
				mark_Lab.size = fix( next_word( menu(sel)))/100.
				print,  " " + mark_Lab(0).symbol + $
					" size=", mark_Lab(0).size
			   endif
		  endif else begin
			menu = ["select Label size:",$
				strtrim( (findgen(10)+1)/2 ) ]
			init = fix( mark_Lab(0).size * 2 )
			sel = wmenu( menu, INIT=init, TIT=0 )
			if (sel GT 0) then begin
				mark_Lab.size =  float( next_word( menu(sel) ) )
		   		print," Label size:",mark_Lab(0).size
			   endif
		   endelse
		END

	  "symbol": BEGIN
			menu = ["select source symbol:",$
				" ",			$
				"cross",		$
				"asterisk",		$
				"box",			$
				"diamond",		$
				"circle"		]
			init = where( mark_Lab.symbol EQ menu )	
			sel = wmenu( menu, INIT=init(0)>2, TIT=0 )
			if (sel GT 1) then begin
				mark_Lab.symbol = next_word( menu(sel) )
				print," source symbol: ",mark_Lab(0).symbol
			   endif
		     END

	   "thickness": BEGIN
			menu = ["select symbol thickness:",$
				strtrim( indgen(7)+1 ) ]
			init = fix( mark_Lab(0).thickness )
			sel = wmenu( menu, INIT=init, TIT=0 )
			if (sel GT 0) then begin
			     mark_Lab.thickness = float( next_word( menu(sel)))
			     print," symbol thickness =",mark_Lab(0).thickness
			   endif
		     END

	     else:	print," setting of ",attributes," not available"
	  ENDCASE
end