;+
; PURPOSE:
; CALLING:
;	display_mosaic, mosaic, mosaic_spec
; INPUT:
;	mosaic = 2D image array.
;	mosaic_spec = structure with contour display specifications.
; HISTORY:
;	Frank Varosi STX @ NASA/GSFC 1989.
;-
pro display_mosaic, mosaic, mosaic_spec, XPOS=xpos, YPOS=ypos, WINDOW=mwindow

	mosaic_scaled = scale_mosaic( filter_mosaic( mosaic, mosaic_spec ), $
						     mosaic_spec, /COLORSCALE )
	color_st_Load, mosaic_spec.colors

	if (mosaic_spec.filter EQ "none") then info = "" $
		else	info = mosaic_spec.filter + $
			"(" + strtrim( mosaic_spec.filt_width, 2 ) + ")"

	info = info + " " + mosaic_spec.scaling
	maxchar = (2 + strlen( info ) ) > strlen( mosaic_spec.winame )

	s = size( mosaic_scaled )
	nx = s(1) > (!D.x_ch_size * maxchar)
	ny = (s(2) + !D.y_ch_size + 8)

	imos = mosaic_spec.number-1
	if N_elements( xpos ) NE 1 then  xpos = ( imos*200 )
	if N_elements( ypos ) NE 1 then  ypos = ( 200 + imos*100 )
	xpos = xpos < (!DEVX-nx)
	ypos = ypos < (!DEVY-ny)

	if N_elements( mwindow ) ne 1 then begin
		internal = 1
		mwindow = mosaic_spec.windo
	   endif

	get_window, mwindow, TITLE = mosaic_spec.winame, XSIZ=nx, YSIZ=ny, $ 
						XPOS=xpos, YPOS=ypos,/SHOW
	tv, mosaic_scaled
	printw, info, /ERASE

	if keyword_set( internal ) then begin
		mosaic_spec.windo = mwindow
		mosaic_spec.wx = 0
		mosaic_spec.wy = 0
		mosaic_spec.display = "DISPLAY"
		mosaic_spec.rot_applied = 0
	   endif
end