; Define structures used in Mega-Grains Escape Probability (MGEP) model
;  for which the code is in mg_ep_2phase.pro (pro MG_EP_2phase):

if N_struct( geometry ) ne 1 then $
		geometry = {	R: 1.0,      $	;radius (pc) of sphere/cylinder.
				H: 0.0,      $	;height of disk/cylinder.
				Volume: 0.0, $  ;(computed by code).
				Reff: 0.0    }	;effective radius (computed).

;If H > 0 then model will be for disk/cylinder, otherwise a sphere if H=0.
;note:  setting H = 2*R will give almost spherical model with Reff = R.

;The clump parameters:
;(note: radii in geometry and clumpy are in parsecs)

if N_struct( clumpy ) ne 1 then $
	clumpy = {	fill_fact: 0.1,		$ ;filling factor of clumps.
			dens_ratio: 0.01,	$ ;ratio of ICM/clump density.
			Clump_ICM_Ratio: 100. ,	$ ;clump/ICM density (alternate)
			Rcl: 0.05, 		$ ;radius of a clump (pc).
			Ncl: 0L			} ;# of clumps (computed)

;Must specify these params of dust and gas:
; 		medium.fsil		(ratio of silicates to total dust mass)
;					(then  fc = 1 - fsil)
;		medium.Dust_Mass_Dens   (gm/cm^3)
;		medium.gas_dens		(n(H)/cm^3)
; to run model.

if N_struct( medium ) ne 1 then $
		medium = {	fsil: 1.0,	$	;silicate mass frac.
				fc: 0.0,	$	;graphite mass frac.
				Dust_Gas_Ratio: 0.0,	$
				Dust_Mass_ICM: 0.0,	$
				Dust_Mass_CL: 0.0,	$
				Dust_Mass: 0.0,		$; in solar masses
				Dust_Mass_Dens: 0.0,	$; gm/cm^3
				Dust_Mass_Dens_ICM: 0.0,$
				Dust_Mass_Dens_CL: 0.0,	$
				gas_dens: 0.0,		$; n(H)/cm^3
				gas_temp: 7e3,		$
				gas_dens_ICM: 0.0,	$
				gas_dens_CL: 0.0	}

;Option to set indices for dust temperature distribution around central source,
; default is case of Optically thin dust (Lindex = 2) :

if N_struct( tdistparm ) ne 1 then $
		tdistparm = {	Lindex_Sil: 2.0,$	;Luminosity and Density
				Lindex_C: 2.0,	$	;  variation indices
				Dindex_ICM:0.0,	$	;  for Temperature
				Dindex_CL:0.0	}	;  distribution model.

;Optional definition of black-body source:

if N_struct( source ) ne 1 then $		;def = HeI emission line stars.
		source = {	T_star: 15000.,$
				L_star: 3.3e4, $
				N_star: 1,     $
				R_star: 0.0,   $
				Src_Type: ""   }

;Finally, pro MG_EP_2phase requires as input the Dust_Kappa structure,
; which is usually contained in IDL/XDR file Dust_Kappa_*.idl, and
; consult the header info of mg_ep_2phase.pro for details.