;******************************************************************************
;+
;*NAME:
;
;	ARTIFACT		1989 August 7
;
;*CLASS:
;
;	File Retrieval
;
;*CATEGORY:
;
;*PURPOSE:
;
;	To retrieve fits files which display low dispersion IUE camera
;	artifacts.
;
;*CALLING SEQUENCE:
;
;	ARTIFACT,WCAMART,FCAMART
;
;*PARAMETERS:
;
;	WCAMART	(REQ) (O) (1) (ILFD)
;		Wavelength vector in angstroms.
;
;	FCAMART (REQ) (O) (1) (ILFD)
;		Flux vector in ergs/cm2/a/s.
;
;*EXAMPLES:
;
;	To generate arrays of wavelength and flux for IUE artifacts:
;
;	     artifact,wcamart,fcamart
;
;	user is prompted for camera name and source type (pt or ext)
;
;
;       To obtain values directly for LWP point source spectra:
;
;            ifitsrd,!iuer.dat+'lwpskyp.fit',1,main,extd,h,wart,fart,e
;
;*SYSTEM VARIABLES USED:
;
;	!iuer.dat
;
;INTERACTIVE INPUT:
;
;	User is prompted to input camera name (lwp, lwr, or swp) and processing
;	type (i.e. point source or extended)
;
;SUBROUTINES CALLED:
;
;	PARCHECK
;	IFITSRD
;
;*FILES USED:
;
;       (in !iuer.dat)
;	LWPSKYP.FIT	(LWP point source)
;	LWPSKYE.FIT	(LWP extended source)
;	LWRSKYP.FIT	(LWR point source)
;	LWRSKYE.FIT	(LWR extended source)
;	SWPSKYP.FIT	(SWP point source)
;	SWPSKYE.FIT	(SWP extended source)
;
;*SIDE EFFECTS:
;
;*RESTRICTIONS:
;
;	Only applicable to low dispersion data.
;
;*NOTES:
;
;	The "spectra" were obtained by averaging numerous sky background 
;	exposures, all of which were at least 3 hours in duration.  These 
;	features will only appear in long exposures.  N. b.:  The actual 
;	numerical values for the fluxes (in ergs/cm2-s-A) of the "features" is
;	indicative of their relative strengths, but should not be used as a 
;	measure of their real values.  The strength of these "features" is 
;	dependent upon exposure time.  See Bruegman and Crenshaw (1989, IUE 
;	NASA Newsletter, 37, 36).
;
;       The HEADER vector of the fits files contains information from one of;
;	the averaged images, and the EPSILON vector contains time-integrated
;	flux values.  Neither vector is used by ARTIFACT.
;
;*PROCEDURE:
;
;	The user is prompted for the correct camera and processing type.
;	The appropriate file (in fits format) is retrieved with IFITSRD.
;
;*I_HELP nn:
;
;*MODIFICATION HISTORY:
;
;	Original version written by T. J. Teays, 1989 Aug 7.
;	    (SAV files were provided by D. M. Crenshaw)
;       8-30-89 RWT modified for SUN IDL
;       4-10-91 KBC branched filename structure based on operating system type
;	6-27-91 PJL new directory structure environment variable with getenv;
;		    added error checking for prompted values; cleaned up; 
;		    tested on SUN and VAX; updated prolog
;	16 Aug 93  PJL  converted sav format files to fits format; replaced
;			IUEFETCH with IFITSRD
;        2 Sep 94  LLT  replace getenv(iuer_dat) with !iuer.dat
;-
;*******************************************************************************
 pro artifact,wcamart,fcamart
;
 npar = n_params(0)
 if (npar eq 0) then begin
    print,'ARTIFACT,WCAMART,FCAMART'
    retall
 endif  ; npar eq 0
 parcheck,npar,2,'ARTIFACT'
;
 inst = 'x'
 proctype = 'x'
 file = 'x'
 read,'Enter camera (lwp, lwr, swp)  ',inst
 if ((strlowcase(inst) ne 'lwp') and (strlowcase(inst) ne 'lwr') and  $
     (strlowcase(inst) ne 'swp')) then begin
    print,'Invalid choice'
    print,'ACTION:  Returning'
    retall
 endif  ; inst
;
 read,'Enter processing type, point source (p) or extended (e)  ',proctype
 if ((strlowcase(proctype) ne 'p') and (strlowcase(proctype) ne 'e'))   $
     then begin
    print,'Invalid choice'
    print,'ACTION:  Returning'
    retall
 endif  ; proctype
;
 fnget = ' '
;
 fnget = inst + 'sky' + proctype + '.fit'
 file = !iuer.dat + fnget
 ifitsrd,strlowcase(file),1,main,extd,hcamart,wcamart,fcamart,ecamart,/silent
;
 return
 end  ; artifact